java中i=i++问题分析【转载】

有这么一道java题目，让人觉得很费解：

int i = 0;
i = i++;
System.out.println(i);

i打印出的结果是0！！相同的表达式在C中则是我们所想象的1！！这个问题从字节码角度考虑就比较容易理解了。下面给出我搜到的一个分析的比较清楚的帖子，给大家看看：
原帖地址：http://piaoboqiu.blog.163.com/blog/static/123127827200910192122472/
具体测试一下以说明问题：
代码1：

public class Test{
 public static void main(String[] args){
 int i=0;
 i=i++;
 System.out.println(i);
 }
}

结果i依然是0.分析其反编译后的代码：

public static void main(java.lang.String[]);
 Code:
 0: iconst_0 //0放到栈顶
 1: istore_1 //把栈顶的值保存到局部变量1，也就是i中
 2: iload_1 //把i的值放到栈顶，也就是说此时栈顶的值是0
 3: iinc 1, 1 //注意这个指令，把局部变量1，也就是i，增加1，这个指令不会导致栈的变化，也就是说局部变量1，即i此时为1了。
 6: istore_1 //把栈顶的值（0）保存到局部变量1，也就是让i为0了，所以最后i为0
 7: getstatic #2; //Field java/lang/System.out:Ljava/io/PrintStream;
 10: iload_1
 11: invokevirtual #3; //Method java/io/PrintStream.println:(I)V
 14: return

值得注意到是i被修改了两次，第一次是i++；i变为1，最后一次是i=0；所以结果i是0
代码2：

public class Test2{
 public static void main(String[] args){
 int i=0;
 int j=0;
 j=i++;
 System.out.println(i);
 System.out.println(j);
 }
}

这个结果肯定都知道，i是1，j是0.同样看反编译之后的代码：

public static void main(java.lang.String[]);
 Code:
 0: iconst_0
 1: istore_1 //i=0
 2: iconst_0
 3: istore_2 //j=0
 4: iload_1 //把i的值放到栈顶，也就是说此时栈顶的值是0
 5: iinc 1, 1 //局部变量1加1，也就是让i++了，此时i已经是1了，上面说过，此指令不会导致栈变化
 8: istore_2 //把栈顶的值（注意是0）存入局部变量2，也就是j中，所以j=0
 9: getstatic #2; //Field java/lang/System.out:Ljava/io/PrintStream;
 12: iload_1
 13: invokevirtual #3; //Method java/io/PrintStream.println:(I)V
 16: getstatic #2; //Field java/lang/System.out:Ljava/io/PrintStream;
 19: iload_2
 20: invokevirtual #3; //Method java/io/PrintStream.println:(I)V
 23: return

很明显可以看出，java是先把i的值取出来放到栈顶，我们可以认为是引入了第三个变量int k=i;然后i++,这时候i为1了，然后让j=k;也就是0.结论，i的++运算是在对j这个变量的赋值之前完成的。
代码3：

public class Test3{
 public static void main(String[] args){
 int i=0;
 int j=0;
 j=++i;
 System.out.println(i);
 System.out.println(j);
 }
}

结果大家也都知道，i=1，j=1
看操作过程：

public static void main(java.lang.String[]);
 Code:
 0: iconst_0
 1: istore_1 //i=0
 2: iconst_0
 3: istore_2 //j=0
 4: iinc 1, 1 //局部变量i加1，这时候i变成1了 。
 7: iload_1 //把i的值放到栈顶,栈顶的值是1
 8: istore_2 //j=1
 9: getstatic #2; //Field java/lang/System.out:Ljava/io/PrintStream;
 12: iload_1
 13: invokevirtual #3; //Method java/io/PrintStream.println:(I)V
 16: getstatic #2; //Field java/lang/System.out:Ljava/io/PrintStream;
 19: iload_2
 20: invokevirtual #3; //Method java/io/PrintStream.println:(I)V
 23: return

对比代码2和代码3，关键的差别就是iload_1   个iinc这两条指令的位置变了。
上面这个帖子偏重于底层，对于java字节码不熟悉的童鞋可能一时不会理解，没关系，下面我贴出另一个帖子，大家应该就明白了：
原帖地址：http://www.ticmy.com/?p=43

结果还是0
为什么？
程序的执行顺序是这样的：因为++在后面，所以先使用i，“使用”的含义就是i++这个表达式的值是0，但是并没有做赋值操作，它在整个语句的最后才做赋值，也就是说在做了++操作后再赋值的，所以最终结果还是0
让我们看的更清晰点：

这是java里的实现，当然在其他的语言如c或是c++中可能并不是这么处理的，每种语言都有各自的理由去做相应的处理。
这警示我们:不要在单个的表达式中对相同的变量赋值超过一次
让我们从字节码层次看一看，源码如下：

使用javac编译后再使用javap -c Test反编译这个类查看它的字节码，如下（只摘取main方法）：
public static void main(java.lang.String[]);
Code:
0: iconst_0
1: istore_1
2: iload_1
3: iinc 1, 1
6: istore_1
7: getstatic #2; //Field java/lang/System.out:Ljava/io/PrintStream;
10: iload_1
11: invokevirtual #3; //Method java/io/PrintStream.println:(I)V
14: return
这里，我从第0行开始分析（分析中【】表示栈，栈的底端在左边，顶端在右边）：
0：将常数0压入栈，栈内容：【0】
1：将栈顶的元素弹出，也就是0，保存到局部变量区索引为为1（也就是变量i）的地方。栈内容：【】
2：将局部变量区索引为1（也就是变量i）的值压入栈，栈内容：【0】
3：将局部变量区索引为1（也就是常量i）的值加一，此时局部变量区索引为1的值（也就是i的值）是1。栈内容：【0】
6：将栈顶元素弹出，保存到局部变量区索引为1（也就是i）的地方，此时i又变成了0。栈内容：【】
7：获取常量池中索引为2所表示的类变量，也就是System.out。栈元素：【】
10：将局部变量区索引为1的值（也就是i）压入栈。栈元素：【0】
11：调用常量池索引为3的方法，也就是System.out.println
14：返回main方法